NONMEM Users Network Archive

Hosted by Cognigen

Re: parent drug and metabolite

From: Nick Holford <n.holford>
Date: Mon, 05 Mar 2007 13:43:52 +1300

Sam,

There is no problem with using CL1 in this code. This is not a reserved word and CL is not a required variable name when using $DES.

I fixed the more obvious errors so that the following code will run with NM-TRAN. However, the equations for parent and metabolites dont make sense to me. It looks like Amounts are being multiplied by volumes when they should be divided in order to get concentration.

Nick

$PROBLEM Parent drug & active metabolite
;Units: Time=mins,
;Concentration=uM(umols/L), Amount=umols
;Age=yrs, Weight=kg
$DATA AW2.CSV IGNORE=#
$INPUT ID TIME DV ANUM AMT SEX=DROP WT AGE CMT

$SUBROUTINE ADVAN6 TRANS1 TOL=5
$MODEL
COMP=(PARENT) COMP=(METAB1) COMP=(METAB2)

$PK
CL1=THETA(1)*EXP(ETA(1))
V1=THETA(2)*EXP(ETA(2))
K20=THETA(3)*EXP(ETA(3))
Q=THETA(4)*EXP(ETA(4))
V2=THETA(5)*EXP(ETA(5))
V3=THETA(6)*EXP(ETA(6))
S1=V1
S2=V2
K12=CL1/V1

$DES
DADT(1)=-CL1*A(1)/V1
DADT(2)=CL1*A(1)/V1+Q/V3*A(3)-Q/V2*A(2)-K20*A(2)
DADT(3)=Q/V2*A(2)-Q/V3*A(3)

$ERROR
W=F
IPRED=F
IRES=DV-IPRED
IWRES=IRES/W
P1=0
IF(CMT.EQ.1)P1=1
P2=0
IF(CMT.EQ.2)P2=1
Y1=W*(1+ERR(1))
Y2=W*(1+ERR(2))
Y=P1*Y1+P2*Y2

$THETA
(0,,100000) ; CL1
(0,,100000) ; V1
(0,,100000) ; K20
(0,,100000) ; Q
(0,,100000) ; V2
(0,,100000) ; V3
$OMEGA
0.1 ; PPV_CL1
0.1 ; PPV_V1
0.1 ; PPV_K20
0.1 ; PPV_Q
0.1 ; PPV_V2
0.1 ; PPV_V3
$SIGMA
0.1 ; RUV_P
0.1 ; RUV_M

;$ESTIMATION MAXEVAL=9999 PRINT=5 POSTHOC
;$COVARIANCE
$TABLE ID TIME DV ANUM AMT WT AGE CMT EVID MDV IPRED IWRES
NOPRINT ONEHEADER FILE=OUTAMIWR.FIT


Sam Liao wrote:
>
> Hi Zheng:
> It is complaining the CL1. You need to replace all CL1 with CL. But
> you have other problems in your $INPUT statement and the data set too.
>
> Sam
> > Dear All:
> >
> > why do I get following error message with the following code? Any
> > opinions regarding this problem and code will be highly appreciated.
> > Thank you very much for your consideration and help. I am modeling
> > parent drug and active metabolite at the same time with this code.
> >
> >
> > AN ERROR WAS FOUND IN THE CONTROL STATEMENTS.
> >
> > AN ERROR WAS FOUND ON LINE 13 AT THE APPROXIMATE POSITION NOTED:
> > CL1=THETA(1)*EXP(ETA(1))
> > X
> > THE CHARACTERS IN ERROR ARE:
> > 202 FORTRAN SYNTAX IS INCORRECT OR INAPPROPRIATE IN THIS CONTEXT.
> > 4
> >
> >
> > $PROBLEM Parent drug & active metabolite ;Units: Time=mins,
> > Concentration=uM(umols/L), Amount=umols
> > ;Age=yrs, Weight=kg
> > $DATA AW2.CSV IGNORE=C $INPUT ID TIME DV ANUM AMT SEX WT AGE CMT EVID MDV
> >
> > $SUBROUTINE ADVAN6 TRANS1 TOL=5
> > $MODEL
> > COMP=(PARENT) COMP=(METAB1) COMP=(METAB2)
> >
> > $PK
> > CL1=THETA(1)*EXP(ETA(1))
> > V1=THETA(2)*EXP(ETA(2))
> > K20=THETA(3)*EXP(ETA(3))
> > Q=THETA(4)*EXP(ETA(4))
> > V2=THETA(5)*EXP(ETA(5))
> > V3=THETA(6)*EXP(ETA(6))
> > S1=V1
> > S2=V2
> > K12=CL1/V1
> >
> > $DES
> > DADT(1)=-CL1*A(1)/V1
> > DADT(2)=CL1*A(1)/V1+Q/V3*A(3)-Q/V2*A(2)-K20*A(2)
> > DADT(3)=Q/V2*A(2)-Q/V3*A(3)
> >
> > $ERROR
> > W=F
> > IPRED=F
> > IRES=DV-IPRED
> > IWRES=IRES/W
> > P1=0
> > IF(CMT.EQ.1)P1=1
> > P2=0
> > IF(CMT.EQ.2)P2=1
> > Y1=W*(1+ERR(1))
> > Y2=W*(1+ERR(2))
> > Y=P1*Y1+P2*Y2
> >
> > $THETA
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > $OMEGA
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> > $SIGMA
> > (0,,0.1000E+07)
> > (0,,0.1000E+07)
> >
> > $ESTIMATION MAXEVAL=9999 PRINT=5 POSTHOC
> >
> > $COVARIANCE
> >
> > $TABLE ID TIME DV ANUM AMT SEX WT AGE CMT EVID MDV IPRED IWRES
> > NOPRINT ONEHEADER FILE=OUTAMIWR.FIT
> >
> > ID Time DV Anum AMT Gender WT Age CMT
> > 1 0 0 1 3371.43 F 110.23 44 1
> > 1 1 187 1 0 F 110.23 44 1
> > 1 1 14.24 1 0 F 110.23 44 2
> > 1 5 85.55 1 0 F 110.23 44 1
> > 1 5 28.49 1 0 F 110.23 44 2
> > 1 15 12.1 1 0 F 110.23 44 1
> > 1 15 13.43 1 0 F 110.23 44 2
> > 1 30 1.03 1 0 F 110.23 44 1
> > 1 30 3.25 1 0 F 110.23 44 2
> > 1 45 1.19 1 0 F 110.23 44 2
> > 1 60 0.83 1 0 F 110.23 44 2
> > 1 120 0.4 1 0 F 110.23 44 2
> > 1 180 0.35 1 0 F 110.23 44 2
> > 1 240 0.13 1 0 F 110.23 44 2
> >
> > Zheng
> >
> >
> >
> >
> >

--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
email:n.holford
http://www.health.auckland.ac.nz/pharmacology/staff/nholford/
Received on Sun Mar 04 2007 - 19:43:52 EST

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com.

Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.