NONMEM Users Network Archive

Hosted by Cognigen

Re: Any solutions to both "minimization terminated" and "high" relative bioavailability

From: Nick Holford <n.holford>
Date: Fri, 22 Aug 2008 07:55:56 +1200

Hong-Guan,

You can ignore the rounding error and additional problem warnings. They
dont mean anything useful. You should look at your parameter values to
see if they are sensible (clearly they are not for 2 of the
bioavailibility fractions) and also use things like a VPC to decide if
the model is fitting the data (see
http://www.page-meeting.org/pdf_assets/8694-Karlsson_Holford_VPC_Tutorial_hires.pdf).

To avoid unrealistic estimates for bioavailability you can try setting
initial estimates for bioavailability fractions to something sensible
and use constraints e.g. instead of this
 (0,4.93) ;f13
write this
 (0,.7,1) ;f13

Nick

Hong-Guang Xie wrote:
> Dear NONMEM Users,
>
> Recently I combined six popPK studies (STDY) together as a whole and
> tried to re-estimate the pop PK parameters of that drug in the
> population with a wide range of the age and body weight. In the pooled
> dataset, all subjects were given with a single dose of that drug. Part
> of the control stream was provided as follows. Based on the prior
> knowledge that a two-compartment model with first-order absorption and
> elimination is used to describe its PK profile well, a two-compartment
> model was used for my meta-popPK analysis. After the NM run for the
> additive or proportional error model or both, the NM indicated that
> "*MIN*IMIZATION *T*ERMINATED DUT TO ROUNDING ERRORS (ERROR=134)"
> alone or in combination with "ADDITIONAL PROBLEMS OCCURED WITH THE
> MINIMIZATION. REGARD THE RESULTS OF THE ESTIMATION STEP CAREFULLY, AND
> ACCEPT THEM ONLY AFTER CHECKING THE COVARIANCE STEP PRODUCES
> REASONABLE OUTPUT".
>
> In addition, the typical values of the relative bioavailability (*F1*)
> was estimated as 5 - 8 for STDY 3 (that is, f13), 9 -14 for STDY 5 (or
> f15) and 0.4 - 0.53 for STDY 6 (f16). Obviously, only f16 seems to be
> reasonable. The drug used in the STDY 3 and 5 was given
> extravascularly, and thus their F1 values should be less than 1. To
> fix these problems, I have made many efforts but failed. For this, I
> would appreciate your time and suggestions.
>
> Thank you,
>
> Hong-Guang Xie
>
> ==================
> ............
>
> $SUBROUTINE ADVAN4 TRANS4
>
> $PK
> ETAMX = 10
>
> SI1=0
> SI2=0
> SI3=0
> SI4=0
> SI5=0
> SI6=0
>
> IF (STDY .EQ. 1) SI1=1 ; iv
> IF (STDY .EQ. 2) SI2=1 ; iv
> IF (STDY .EQ. 3) SI3=1 ; epidural
> IF (STDY .EQ. 4) SI4=1 ; iv
> IF (STDY .EQ. 5) SI5=1 ; rectal
> IF (STDY .EQ. 6) SI6=1 ; oral
>
> IV = SI1+SI2+SI4 ;intravascular dosing
>
> ;APPARENT CLEARANCE
> TVCL=popcl
> PPVCL=bsvcl
> IF (ABS(PPVCL) .GE. ETAMX) EXIT 1 10
> CL=TVCL*EXP(PPVCL)
>
> ;CENTRAL VOLUME OF DISTRIBUTION
> TVV2=popv2
> PPVV2=bsvv2
> IF (ABS(PPVV2) .GE. ETAMX) EXIT 1 20
> V2=TVV2*EXP(PPVV2)
>
> ;INTERCOMPARTMENTAL CLEARANCE
> TVQ=popq
> PPVQ=bsvq
> IF (ABS(PPVQ) .GE. ETAMX) EXIT 1 30
> Q=TVQ*EXP(PPVQ)
>
> ;PERIPHERAL VOLUME OF DISTRIBUTION
> TVV3=popv3
> PPVV3=bsvv3
> IF (ABS(PPVV3) .GE. ETAMX) EXIT 1 40
> V3=TVV3*EXP(PPVV3)
>
> ;FIRST ORDER ABSORPTION RATE CONSTANT
> TVKA=SI3*ka3+SI5*ka5+SI6*ka6
> PPVKA=bsvka
> IF (ABS(PPVKA) .GE. ETAMX) EXIT 1 50
> KA=TVKA*EXP(PPVKA)
>
> ;LAG TIME
> TVLAG=SI3*lag3+SI5*lag5+SI6*lag6
> PPVLAG=bsvlag
> IF (ABS(PPVLAG) .GE. ETAMX) EXIT 1 60
> ALAG1=TVLAG*EXP(PPVLAG)
>
> ;BIOAVAILABILITY (BA)
> TVF1=SI3*f13+SI5*f15+SI6*f16
> PPVF1=bsvf1
> IF (ABS(PPVF1) .GE. ETAMX) EXIT 1 70
> BA=TVF1*EXP(PPVF1)
>
> IF (IV .GE. 1) THEN
> F1=1
> ELSE
> F1=BA
> ENDIF
>
> ;ZERO ORDER ABSORPTION DURATION
> TVD2=SI1*d21+SI2*d22+SI4*d24
> PPVD2=bsvd2
> IF (ABS(PPVD2) .GE. ETAMX) EXIT 1 80
> D2=TVD2*EXP(PPVD2)
>
> RMIN=AMT/(60*D2) ;mcg/minute
>
> ; SCALING FOR CENTRAL COMPARTMENT (I.E., CONCENTRATION COMPARTMENT)
>
> S2=V2 ; DOSE IN MCG, CONCENTRATION IN NG/ML=MCG/L
>
> $ERROR
>
> IPRED = F
>
> IF (MDV .EQ. 0) THEN
> W = SQRT(add**2 + F*F*prop**2)
> ELSE
> W = 1
> ENDIF
>
> IRES=DV-IPRED
>
> IF (W .EQ. 0) THEN
> IWRES=IRES
> ELSE
> IWRES=IRES/W
> ENDIF
>
> Y=F+W*eps1*EXP(bsvres)
>
> $THETA (0,11.5) ;popcl
> (0,24.1) ;popv2
> (0,12.9) ;popq
> (0,8.22) ;popv3
> (0,0.14) ;ka3
> (0,0.109) ;ka5
> (0,0.397) ;ka6
> (0 FIX) ;lag3
> (0 FIX) ;lag5
> (0 FIX) ;lag6
> (0,4.93) ;f13
> (0,9.19) ;f15
> (0,0.523) ;f16
> (0,0.00072) ;d21
> (0,0.00007) ;d22
> (0,0.00003) ;d24
> (0, 0.01) ;add
> (0, 0.05) ;prop
>
> $OMEGA 0.828 ;bsvcl
> $OMEGA 1.63 ;bsvv2
> $OMEGA 0 FIX ;bsvq
> $OMEGA 0 FIX ;bsvv3
> $OMEGA 0 FIX ;bsvka
> $OMEGA 0 FIX ;bsvlag
> $OMEGA 0 FIX ;bsvf1
> $OMEGA 0 FIX ;bsvd2
> $OMEGA 0 FIX ;bsvres
>
> $SIGMA 1. FIX ; eps1
>
> $ESTIMATION NOABORT MAXEVAL=9999 POSTHOC PRINT=5 SIGDIGITS=3 MSFO=
> METHOD=CONDITIONAL INTERACTION
>
> ;$COV PRINT=E
>
> $TABLE ID STDY TIME DV IPRED AMT MDV CMT CL V2 Q V3 KA ALAG1 F1 D2
> RATE RMIN ETA1 ETA2 ETA3 ETA4 ETA5 ETA6 ETA7 ETA8 ETA9
> IWRES IRES WT BWT AGEY AGED GAGE
> NOPRINT ONEHEADER FILE=
> ===================================================================================

--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
n.holford
http://www.fmhs.auckland.ac.nz/sms/pharmacology/holford

Received on Thu Aug 21 2008 - 15:55:56 EDT

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com.

Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.