NONMEM Users Network Archive

Hosted by Cognigen

Re: Estimation of standard error

From: Leonid Gibiansky <LGibiansky>
Date: Thu, 03 Jul 2008 15:00:43 -0400

Huali and Nick,
Failure of $COV step sometimes tells about errors in the code. In this
case, I think the problem is in
S2 = V1

should it be
S2 = V2 ?

Also,
> Y1=F+F*EPS(1)
> Y2=F+F*EPS(1)
> Y=R1*Y1+R2*Y2

results in
Y =F+F*EPS(1)
for both MCT=1 and CMT=2
so R1 / R2 /Y1 /Y2 part can be omitted. Or you can use separate errors
for each CMT:

> Y1=F+F*EPS(1)
> Y2=F+F*EPS(2)
> Y=R1*Y1+R2*Y2
--

S2 = V2 should help to get SE. If not, try MATRIX=S on $COV line.
Leonid

--------------------------------------
Leonid Gibiansky, Ph.D.
President, QuantPharm LLC
web: www.quantpharm.com
e-mail: LGibiansky at quantpharm.com
tel: (301) 767 5566




Huali Wu wrote:
> Dear NMusers:
>
> I am trying to fit a data set with concentrations of encapsulated drug
> and released drug. These concentrations were measured after an hour
> infusion of encapsulated drug. The problem is that I cannot get standard
> error estimated from simultaneous fitting of all the data. And I got an
> error message as below:
>
> MINIMIZATION SUCCESSFUL
> HOWEVER, PROBLEMS OCCURRED WITH THE MINIMIZATION.
> REGARD THE RESULTS OF THE ESTIMATION STEP CAREFULLY, AND ACCEPT THEM ONLY
> AFTER CHECKING THAT THE COVARIANCE STEP PRODUCES REASONABLE OUTPUT.
> NO. OF FUNCTION EVALUATIONS USED: 968
> NO. OF SIG. DIGITS IN FINAL EST.: 3.2
> R MATRIX ALGORITHMICALLY NON-POSITIVE-SEMIDEFINITE
> BUT NONSINGULAR
> R MATRIX IS OUTPUT
> COVARIANCE STEP ABORTED
>
> But if I fit the encapsulated drug first and then fit data of both
> encapsulated drug and released drug by fixing the typical values of
> parameters associated with encapsulated drug compartment, I can get an
> estimation of standard errors. And GOF plots look good.
>
> So my question is can I use this stepwise strategy to build up my base
> model? If not, what can I do to get standard error estimated in
> simultaneous fitting?
>
> Any comment or suggestion will be highly appreciated.
>
> Below is my code:
>
> $SUBROUTINES ADVAN9 TRANS1 TOL=3
> $MODEL NPAR=8, NCOMP=3, COMP=(CENTRAL,DEFOBS),
> COMP=(PERIPH1), COMP=(PERIPH2)
>
> $PK
> V1 = THETA(1)*EXP(ETA(1))
> V2 = THETA(2)*EXP(ETA(2))
> V3 = THETA(3)
> VM = THETA(4)
> KM = THETA(5)
> Q2 = THETA(6)*EXP(ETA(3))
> Q3 = THETA(7)
> Q4 = THETA(8)
> S1 = V1
> S2 = V1
>
> $ERROR
>
> R1=0
> IF (CMT.EQ.1) R1=1
> R2=0
> IF (CMT.EQ.2) R2=1
> Y1=F+F*EPS(1)
> Y2=F+F*EPS(1)
> Y=R1*Y1+R2*Y2
> IPRED=F
> IRES=DV-IPRED
>
> $DES
> C1 = A(1)/V1
> DADT(1) = - C1*VM/(KM+C1)-Q2*A(1)/V1
> DADT(2) = C1*VM/(KM+C1)+Q2*A(1)/V1 + Q4*A(3)/V3-
> Q3*A(2)/V2-Q4*A(2)/V2
> DADT(3) = Q4*A(2)/V2-Q4*A(3)/V3
>
> $THETA (5.27 FIX) (0, 0.5) (0, 3.38) (0.329 FIX) (4.38 FIX) (0.136 FIX)
> (0, 0.0626) (0, 0.0461)
> $OMEGA (0.01) (0.01) (0.01)
> $SIGMA (.1)
>
> $EST MAXEVAL=9999 PRINT=5
> $COV
> $TABLE ID TIME DV AMT RATE CMT NOPRINT FILE=ENCAP4 ONEHEADER
> $SCAT (RES WRES) VS TIME BY ID
>
> Best regards,
>
> Huali
>
>
Received on Thu Jul 03 2008 - 15:00:43 EDT

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com.

Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.