NONMEM Users Network Archive

Hosted by Cognigen

Re: Metabolite inhibition model

From: Nick Holford <n.holford>
Date: Sat, 20 Sep 2008 08:59:31 +1200

Nick,

You seem to have made at few errors in the NM-TRAN code you sent
yesterday. Perhaps you shouldn't try replying to these kinds of
questions on a Friday night after a couple of glasses of wine!

$INPUT ID TIME DVID DV etc
$SUBROUTINE ADVAN6 TOL=3
$MODEL COMP (LIDO1) COMP (LIDO2) COMP (MEGX)
$PK
;LIDO parameters
V1= THETA(1)*EXP(ETA(1))
CLLIDO=THETA(2)*EXP(ETA(2)) ; Lido clearance in absence of MEGX
V2= THETA(3)*EXP(ETA(3))
Q=THETA(4)*EXP(ETA(4))
;MEGX parameters
KI=THETA(5)*EXP(ETA(5)) ; inhibition constant for MEGX on LIDO clearance
CLMEGX=THETA(6)*EXP(ETA(6))
VMEGX=THETA(7)*EXP(ETA(7))

$DES

DC1=A(1)/V1
DC2=A(2)/V2
DMEGX=A(3)/VMEGX

CL=CLLIDO*(1-DMEGX/(KI+DMEGX)) ;MEGX inhibitory effect on LIDO
clearance. Assumes MEGX can completely inhibit LIDO metabolism.

DADT(1)=Q*DC2−(Q+ CL)*DC1 ;Assumes all LIDO is converted to MEGX
DADT(2)=Q*(DC1−DC2)
DADT(3)=DC1*CL - DMEGX*CLMEGX

$ERROR

CLIDO=A(1)/V1
CMEGX=A(3)/VMEGX
;You need to add DVID data item to your data set to identify which
records are LIDO and which are MEGX observations.
IF (DVID.EQ.1) THEN ; LIDO conc
   Y=CLIDO*(1+ERR(1))
ELSE ; MEGX conc
   Y=CMEGX*(1+ERR(2))
ENDIF

Best wishes,

Nick

Nick Holford wrote:
> Yung-Wei,
>
> If I make the assumption that you have measurements of MEGX as well as
> lidoocaine then you might be able to fit the MEGX and LIDO concs at
> the same time like this:
>
> $SUBROUTINE ADVAN6 TOL=3
>
> $MODEL COMP (ONE) COMP (TWO)
>
> $PK
>
> V1= THETA(1)*EXP(ETA(1))
>
> CLLIDO=THETA(2)*EXP(ETA(2))
>
> KI=THETA(3)*EXP(ETA(3))
>
> V2= THETA(4)*EXP(ETA(4))
>
> Q2=THETA(5)*EXP(ETA(5))
>
> ;add parameters for MEGX here
>
> ...
> $DES
>
> DC1=A(1)/V1
>
> DC2=A(2)/V2
>
> DMEGX=A(3)/VMEGX
> CL=CLLIDO*DMEGX/(KI+DMEGX) ; MEGX effect on LIDO clearance
>
> DADT(1)=Q2*DC2−(Q2+ CL + CLMEGX)*DC1
>
> DADT(2)=Q2*(DC1−DC2)
>
> DADT(3)=DC1*CL2M - DMEGX*CLMEGX
>
>
> $ERROR
>
> C1=A(1)/V1
>
> CMEGX=A(3)/VMEGX
> IF (DVID.EQ.1) THEN ; need to add DVID data item to your data set to
> identify which records are LIDO and which are MEGX
>
> Y=C1*(1+ERR(1))
>
> ELSE
> Y=CMEGX*(1+ERR(2))
> ENDIF
>
> Yung-Wei Hsu wrote:
>>
>> Dear All,
>>
>>
>>
>> I am working on lidocaine PK data from 106 patients receiving
>> infusion for 48 hours. The metabolite (MEGX) will decrease the
>> clearance of the parent drug (lidocaine). Therefore, I analyzed the
>> data with nonlinear PK model (ADVAN6 TOL=3). I am wondering whether
>> there is any metabolite inhibition model to analyze the lidocaine PK.
>>
>>
>>
>> Any comment or suggestion will be highly appreciated.
>>
>>
>>
>> Yung-Wei Hsu
>>
>> Mackay Memorial Hospital
>>
>> Taipei, Taiwan
>>
>> +++++++++++++++++
>>
>> $SUBROUTINE ADVAN6 TOL=3
>>
>> $MODEL COMP (ONE) COMP (TWO)
>>
>> $PK
>>
>> V1= THETA(1)*EXP(ETA(1))
>>
>> VMAX=THETA(2)*EXP(ETA(2))
>>
>> KM=THETA(3)*EXP(ETA(3))
>>
>> V2= THETA(4)*EXP(ETA(4))
>>
>> Q2=THETA(5)*EXP(ETA(5))
>>
>> $DES
>>
>> DC1=A(1)/V1
>>
>> DC2=A(2)/V2
>>
>> CL=VMAX*DC1/(KM+DC1)
>>
>> DADT(1)=Q2*DC2−(Q2+ CL)*DC1
>>
>> DADT(2)=Q2*(DC1−DC2)
>>
>> $ERROR
>>
>> C1=A(1)/V1
>>
>> Y=C1*(1+ERR(1))
>>
>> IPRED=Y
>>
>> ++++++++++++++++++++++++++++++++++++++++++
>>
>>
>>
>>
>>
>>
>> ------------
>> This message has been scanned for viruses and
>> dangerous content.
>

--
Nick Holford, Dept Pharmacology & Clinical Pharmacology
University of Auckland, 85 Park Rd, Private Bag 92019, Auckland, New Zealand
n.holford
http://www.fmhs.auckland.ac.nz/sms/pharmacology/holford
Received on Fri Sep 19 2008 - 16:59:31 EDT

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com.

Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.