NONMEM Users Network Archive

Hosted by Cognigen

RE: PBPK structural model in NONMEM!

From: Serge Guzy <GUZY>
Date: Sun, 13 Dec 2009 00:27:30 -0800

In NONMEM help, you can find information about CMT and I think NONMEM is
using the same logic as SADAPT and PDX-MC-PEM.

CMT specifies the number of the compartment into which the dose is
introduced. Then based on that, when you construct your data set, if
the dose is given in the fourth compartment, you just put cmt=4 at the
time the dosing event occurs and evid must be set to 1 (may be not
necessary with NONMEM but a must in the other programs). If you have
only one single bolus dose, I guess you could use also the initial
condition option available since NONMEM6 (in $PK for example, a dose of
1000 in compartment 4 could be defined by writing A_0(4)= 1000 ) but it
is easier to just input the dose in the data set as it would work for
both single, multiple doses and also dosing through infusion (The you
use both the DOSE and the RATE DATA ITEMS).

Using the data set

 

ID TIME DOSE RATE EVID CMT

1 0 1000 0 1 4

 

Would put a dose of 1000 units in the fourth compartment (fourth
differential equation).

Best Regards;

Serge Guzy; Ph.D

President, CEO, POP_PHARM

 

 

 

From: owner-nmusers
On Behalf Of ke fang
Sent: Saturday, December 12, 2009 10:28 PM
To: nonmem usersgroup
Subject: [NMusers] PBPK structural model in NONMEM!

 

Dear all,

 

  I'm now developing a simple PBPK structural model in NONMEM. The input
to the PBPK model was a i.m. injection, and the only output was the
renal excretion.. Because the drug was a long acting formulation, so I
try to model the absorption into a fast phase and a slow phase. Now,
here comes the problem. I don't know how to get DOSE into the model.
Here is the control stream file:

 

$PROB WBPBPK POPULATION MODEL

$INPUT ID TIME CONC=DV AMT WT EVID CMT

$DATA ..\PBPK.TXT IGNORE=#

$SUBROUTINES ADVAN6 TOL=3

$MODEL

COMP = (LIV) ; 1 - LIVER COMPARTMENT

COMP = (KID) ; 2 - KIDNEY COMPARTMENT

COMP = (MUS) ; 3 - MUSCLE COMPARTMENT

COMP = (INJ) ; 4 - INJECTIONSITE COMPARTMENT RECEIVING DOSE

COMP = (VEN) ; 5 - VENOUS COMPARTMENT

COMP = (OUT) ; 6 - KIDNEY EXCRETION COMPARTMENT

$PK

; ------------------------ TWO ABSORBTION PHASE-------------------- ;

PHSF = 0.714 ; FAST PHASE ABSORPTION FRACTION

PHSS = 0.286 ; SLOW PHASE ABSORPTION FRACTION

KF = 0.032334 ; FAST PHASE ABSORPTION ABSORPTION RATE

KS = 0.00835 ; SLOW PHASE ABSORPTION ABSORPTION RATE

; ------------------------- BLOOD FLOWS (Q,L/HR) -------------------- ;

QVEN = 2.049*WT ;L/H/KG;

QLIV =QVEN*0.3053*(WT/25) ;L/H/KG;

QKID =QVEN*0.1398*(WT/25) ;L/H/KG;

QMUS =QVEN*0.2524*(WT/25) ;L/H/KG;

QINJ = QVEN*0.2524*(0.5/WT/25) ;L/H/KG;

;----------------------------TISSUE VOLUMES (V,L)----------------------;

VLIV =0.0294*WT ;KG;

VKID =0.004*WT ;KG;

VMUS =0.4007*WT ;KG;

VINJ =0.5 ;KG;

VVEN =0.06*WT ;KG;

;----------------------------PARTITION COEFFICIENTS-------------------;

PLIV = EXP(THETA(2))

PKID = EXP(THETA(3))

PMUS = EXP(THETA(4))

;---------------------KIDNEY EXCRETION-------------------;

TVEXCR=EXP(THETA(1))

EXCR=TVEXCR*EXP(ETA(1))

$DES

;--------------------COMPARTMENT CONCENTRATIONS-------------------;

C1 = A(1)/VLIV

C2 = A(2)/VKID

C3 = A(3)/VMUS

C4 = A(4)/VINJ

C5 = A(5)/VVEN

DADT(1)=QLIV*(C5-C1/PLIV)

DADT(2)=(QKID*(C5-C2/PKID)-C2*EXCR)

DADT(3)=QMUS*(C5-C3/PMUS)

DADT(4)=(QINJ*(C5-C4/PMUS))

DADT(5)=(QLIV*C1/PLIV+QKID*C2/PKID+QMUS*C3/PMUS+QINJ*C4/PMUS-QVEN*C5)

DADT(6)=EXCR

$ERROR

Y=A(3)/VMUS+EPS(1)

;------------------------------INITIAL
ESTIMATES--------------------------------;

$THETA(0,0.5) ; 1-EXCR

$THETA(0,1.82,10) ; 2-PLIV

$THETA(0,6.46,10) ; 3-PKID

$THETA(0,0.486) ; 4-PMUS

$OMEGA(0.5) ; 1-EXCR

$SIGMA(1) ; 1-ERROR

$EST PRINT=5 MAX=9990 POSTHOC SIGDIG=3 METHOD=1

$COV MATRIX=R

$TABLE ID TIME CONC WT AMT NOPRINT ONEHEADER FILE=PBPK.FIT

 

Can anyone give some hint?

Thanks in advance!

 

Ke, Fang

 


--
The information contained in this email message may
contain confidential or legally privileged information and is intended sole=
ly
for the use of the named recipient(s). No confidentiality or privilege is=
 
waived or lost by any transmission error. If the reader of this message is=
 
not the intended recipient, please immediately delete the e-mail and all
copies of it from your system, destroy any hard copies of it and notify the=
 
sender either by telephone or return e-mail. Any direct or indirect use,=
 
disclosure, distribution, printing, or copying of any part of this message =
is
prohibited. Any views expressed in this message are those of the individua=
l
sender, except where the message states otherwise and the sender is
authorized to state them to be the views of XOMA.

Received on Sun Dec 13 2009 - 03:27:30 EST

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com.

Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.