NONMEM Users Network Archive

Hosted by Cognigen

Re: Parallel first order and Michaelis-Menten elimination

From: Nick Holford <n.holford>
Date: Sun, 28 Mar 2010 10:44:21 -0700

Leonid,

Thanks for the code example which illustrates one side of a religious
debate which took place a few weeks ago on PharmPK. The essence of this
debate was should one normalize PK parameters to a unit volume or to a
unit body.

The unit volume believers feel that the rate constant is the 'natural'
way to describe pharmacokinetics while the unit body believers feel that
clearance is more 'natural'. Both groups agree that the two systems are
just reparameterizations and make identical numerical predictions.

Your coding of Vmax for the mixed order elimination process has the
implicit units of mass/time per unit volume e.g. mg/h/L. This is the
unit volume belief system.

I am a unit body believer so I would code this system differently with a
very simple change- substituting A(1) with C1 to multiply the mixed
order expression. I have also changed VM to VMUB to indicate that the
dimensions of the Vmax parameter are per unit body i.e. mg/h per body.

DADT(1) = -K10*A(1)-C1*VMUB/(KM+C1)-K12*A(1)+K21*A(2)

It could also be written like this to emphasize that the mixed order
process has the same units as CL (for unit body believers) when C1 tends
to 0:

DADT(1) = -C1*(CL+VMUB/(KM+C1) - K12*A(1)+K21*A(2)

I note also that your residual error model implies that the DV has been
log transformed. This reflects yet another belief system which I think
you have shown has little, if any, practical merit. I prefer to keep the
DV in the original units.

Best wishes,

Nick



Leonid Gibiansky wrote:
> ADVAN6 ADVAN8 or (nm7) ADVAN13
>
> The code is below
>
> Leonid
>
> -------------------
> $SUBROUTINE ADVAN6 TOL=9
>
> $MODEL
> NCOMP = 2
> COMP = (CENTRAL) ;1
> COMP = (PERIPH) ;2
>
> $PK
> CL= THETA(1)*EXP(ETA(1))
> V1= THETA(2)*EXP(ETA(2))
> Q = THETA(3)*EXP(ETA(3))
> V2= THETA(4)*EXP(ETA(4))
> VM= THETA(5)*EXP(ETA(5))
> KM= THETA(6)
>
> K10 = CL/V1
> K12 = Q/V1
> K21 = Q/V2
> S1 = V1
> S2 = V2
>
> $DES
> C1 = A(1)/S1
> DADT(1) = -K10*A(1)-A(1)*VM/(KM+C1)-K12*A(1)+K21*A(2)
> DADT(2) = K12*A(1)-K21*A(2)
>
> $ERROR
> TY = A(1)/V1
> IPRED=TY
> W = SQRT(THETA(7)**2/TY**2+THETA(8)**2)
> Y = IPRED*EXP(W*ERR(1))
>
> $THETA
> .....
>
> $OMEGA
> .....
>
> $SIGMA
> 1 FIX ; ~ERR
>
> --------------------------------------
> Leonid Gibiansky, Ph.D.
> President, QuantPharm LLC
> web: www.quantpharm.com
> e-mail: LGibiansky at quantpharm.com
> tel: (301) 767 5566
>
> chenyuhong
>> Dear All,
>>
>> I am working with a Biologic and would like to have a PK model with
>> parallel first order and Michaelis-Menten elimination. Any suggestion
>> about which subroutine I am supposed to use? If you can share an
>> example for the control stream, that will be a great help.
>>
>> Thanks,
>>
>> Yuhong
>>
>>
>>

--
Nick Holford, Professor Clinical Pharmacology
Dept Pharmacology & Clinical Pharmacology
University of Auckland,85 Park Rd,Private Bag 92019,Auckland,New Zealand
tel:+64(9)923-6730 fax:+64(9)373-7090 mobile:+64(21)46 23 53
email: n.holford
http://www.fmhs.auckland.ac.nz/sms/pharmacology/holford


Received on Sun Mar 28 2010 - 13:44:21 EDT

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com.

Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.