NONMEM Users Network Archive

Hosted by Cognigen

Re: distribution assumption of Eta in NONMEM

From: Nick Holford <n.holford>
Date: Mon, 31 May 2010 18:05:06 +0200

Hi,

I tried to see with brute force how well NONMEM can produce an empirical
Bayes estimate when the ETA used for simulation is uniform. I attempted
to stress NONMEM with a non-linear problem (the average DV is 0.62). The
mean estimate of OMEGA(1) was 0.0827 compared with the theoretical value
of 0.0833.

The distribution of 1000 EBEs of ETA(1) looked much more uniform than
normal.
Thus FOCE show no evidence of normality being imposed on the EBEs.

$PROB EBE
$INPUT ID DV UNIETA
$DATA uni1.csv ; 100 subjects with 1 obs each
$THETA 5 ; HILL
$OMEGA 0.083333333 ; PPV_HILL = 1/12
$SIGMA 0.000001 FIX ; EPS1

$SIM (1234) (5678 UNIFORM) NSUB=10
$EST METHOD=COND MAX=9990 SIG=3
$PRED
IF (ICALL.EQ.4) THEN
   IF (NEWIND.LE.1) THEN
      CALL RANDOM(2,R)
      UNIETA=R-0.5 ; U(-0.5,0.5) mean=0, variance=1/12
      HILL=THETA(1)*EXP(UNIETA)
      Y=1.1**HILL/(1.1**HILL+1)
   ENDIF
ELSE

HILL=THETA(1)*EXP(ETA(1))
Y=1.1**HILL/(1.1**HILL+1) + EPS(1)
ENDIF

REP=IREP

$TABLE ID REP HILL UNIETA ETA(1) Y
ONEHEADER NOPRINT FILE=uni.fit

I realized after a bit more thought that my suggestion to transform the
eta value for estimation wasn't rational so please ignore that senior
moment in my earlier email on this topic.

Nick

--
Nick Holford, Professor Clinical Pharmacology
Dept Pharmacology & Clinical Pharmacology
University of Auckland,85 Park Rd,Private Bag 92019,Auckland,New Zealand
tel:+64(9)923-6730 fax:+64(9)373-7090 mobile:+64(21)46 23 53
email: n.holford
http://www.fmhs.auckland.ac.nz/sms/pharmacology/holford


Received on Mon May 31 2010 - 12:05:06 EDT

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com.

Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.