NONMEM Users Network Archive

Hosted by Cognigen

Re: Problems with PD Modelling

From: Leonid Gibiansky <LGibiansky>
Date: Sat, 12 Feb 2011 10:56:35 -0500

The code looks OK, but I cannot see from the data whether they indeed
correspond to the indirect response with inhibition. Looks like random
oscillations to me. This could be a reason for error messages.

I would try to fix ETA_Kin or ETA_Kout to zero and use only additive (or
proportional) error. Also, it will not help convergence but it is more
mechanistic to use

CONC = A(2)/S2
INH =CONC/(IC50+CONC)

Then IC50 will be in concentrations rather than in amounts.

Also, TOL=3 is to small. Try to use TOL=6 at least (better 7 or 8). Same
for PK: TOL=3 is not good for the final model.

Regards
Leonid

--------------------------------------
Leonid Gibiansky, Ph.D.
President, QuantPharm LLC
web: www.quantpharm.com
e-mail: LGibiansky at quantpharm.com
tel: (301) 767 5566



On 2/11/2011 10:35 AM, xin yi wrote:
> Hi all,
>
> I'm new to nonmem and would be grateful for some pointers and help. I'm
> trying to do a pk-pd sequential modelling. I have modelled the PK data
> but I've encountered problems with PD. My PD model is a indirect
> inhibition response model. I have tried to change my initial estimates
> reduce the number of parameters in the model, but nothing seem to get me
> a good convergence. At different times, NONMEM gives me different error
> messages such as "parameter estimates near its boundary", "Minimisation
> successful. However problems occured with the minimization"(blank
> entries for omega or sigma estimates in the results file) ///or the "r
> matrix is algorithmically singular and non-positive definite". I have a
> few questions:
>
> 1) Are there any errors in the way I input my control and data file?
> 2) Under $ERROR in the control file, did I define it correctly with
> EFF=A(4), Y//=EFF+EFF*ERR(1)+ERR(2)/? Or should it be IPRED=F,
> Y=F+F*ERR(1)+ERR(2).
> 3) Why are they no estimates for sigma and omega in the results file? I
> have been constantly changing my initial estimates for omega and sigma
> but they always give me nil results.
>
> I appreciate any help on this matter. Thanks!
>
> Regards,
> X.Y. Ng
> /
> *This is an example of my control file:*
>
> $PROB RUN# pd_3_advan6
> $INPUT ID TIME DV AMT CMT ADDL II MDV V2I V3I QI CLI KAI
>
> $DATA FINAL2.2.CSV IGNORE=C
> $SUBROUTINES ADVAN6 TRANS1 TOL=3
> $MODEL
> COMP=DEPOT
> COMP=CENTRAL
> COMP=PERIPH
> COMP=EFFECT ;$MODEL defines the no of compartments in the model
>
> $PK
>
> V2=V2I
> V3=V3I
> Q=QI
> CL=CLI
> KA=KAI
> S2=V2
> S3=V3
> KIN=THETA(1)*EXP(ETA(1))
> KOUT=THETA(2)*EXP(ETA(2))
> IC50=THETA(3)*EXP(ETA(3))
> F4=KIN/KOUT
>
> $DES
> DADT(1)=-KA*A(1)
> DADT(2)=KA*A(1)-Q/V2*A(2)+Q/V3*A(3)-CL/V2*A(2)
> DADT(3)=-Q/V3*A(3)+Q/V2*A(2)
> INH =A(2)/(IC50+A(2))
> DADT(4)=KIN*(1-INH)-KOUT*A(4)
>
> $ERROR
> CP2=A(2)/S2
> CP3=A(3)/S3
> ;IPRED=F
> EFF=A(4)
> Y=EFF+EFF*ERR(1)+ERR(2)
>
> $THETA (0,0.281) ;POPKin
> $THETA (0,0.003) ;POPkout
> $THETA (0,2) ;POPIC50
>
> $OMEGA 0.003 ;BSV Kin
> $OMEGA 0.003 ;BSV Kout
> $OMEGA 0.003 ;BSV IC50
>
> $SIGMA 0.01 ;ERRCCV
> $SIGMA 0.0015 ;ERRADD
>
> $ESTIMATION METHOD=1 INTERACTION NOABORT MAXEVAL=9990 PRINT=10 POSTHOC
> $COVARIANCE
> $TABLE ID TIME DV AMT CMT NOPRINT ONEHEADER FILE=pd_3_advan6.TAB
>
> *and an example of my data:*
>
> /
> CID TIME DV AMT CMT ADDL II MDV V2I V3I QI CLI KAI
> 101 0 0 100 1 2 8 1 44.55 11.78 1.07 3.37 0.62
> 101 0 0 1 4 0 0 1 44.55 11.78 1.07 3.37 0.62
> 101 3 243 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 7 293 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 11 261 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 15 260 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 19 277 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 23 290 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 35 233 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 39 271 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 43 274 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
> 101 47 276 0 4 0 0 0 44.55 11.78 1.07 3.37 0.62
>
> /
> /
Received on Sat Feb 12 2011 - 10:56:35 EST

The NONMEM Users Network is maintained by ICON plc. Requests to subscribe to the network should be sent to: nmusers-request@iconplc.com.

Once subscribed, you may contribute to the discussion by emailing: nmusers@globomaxnm.com.